/*

This is a script to create a simple crowd simulation.
To run it, execute the following (it helps to add it to your toolbar):

source CrowdSystem;
crowdMain;

Or, alternatively, drag-and-drop the script into your Maya window
and type "crowdMain" in the command line.

This will open the main window with all of the controls this tool allows.
Please see the attached tutorial for in-depth explanation of all the 
available features.

This script was written by Nikita Pavlov as part of the VIS Project
at Carnegie Mellon University's Entertainment Technology Center. 
It is intended for public use as long as the creator and the university
are acknowledged as listed herein.  This was designed for Maya 6.0. 
Feel free to add modifications and features and share them with us!

*/


// Create crowd
global proc createCrowd (int $iNumAgents,
			 float $fCrowdRad,
			 float $fImpulseRange,
			 int $agentHasAnim,
			 int $agentHasGoal)
{
    global string $agentModel;
    global string $agentCharSet;
    global string $agentAnim[];
    global string $agentSkin;
    global string $agentGoal;
    //global int $agentHasAnim;
    global float $fAnimOffsetRange;
    global float $fAnimSpeedRange;
    //global float $agentCollRadius;
    //global float $fMaxVelocity;
    //global float $fAvgVelocity;
    //global int $collideWithPriorAgents;
    global string $placementPattern[];
    global int $iCrowdRad2D;
    global float $fGenCenter[];
    //global float $fMassMin, $fMassMax;
    //global int $gforces;
    global float $fGoalPriority;

    // Set up the central crowd system object.
    $crowdProxy = `setupCrowdSystemProxy`;

    // Check whether an agent model has been specified.
    string $agentCmd;
    if ($agentModel == "")
    {
        $agentCmd = "polyCube -width 2 -height 2.5 -depth 2;";
    }
    else
    {
        if ($agentHasAnim == 0)
        {
            $agentCmd = "duplicate -rr $agentModel;";
        }
        else
        {
            // If we have animations, duplicate the input graph.
            $agentCmd = "duplicate -rr -renameChildren -un $agentModel;";
            //$agentCmd = "duplicate -rr -un $agentSkin;";
        }
    }

    // Figure out what number to start on.
    int $idxStart = 0;
    while (`objExists ("vehicle_"+$idxStart)`)
        $idxStart++;

    // Basic vehicle model type
    for ($i=$idxStart; $i<$iNumAgents+$idxStart; $i++)
    {
	// Name the agent, since we'll be using this value a LOT.
	$aName = ("agent_" + $i);
	$cName = ("agentCtrl_" + $i);
        // Unfortunately, polyCube produces two results, and we want only the first
	// (hence the array).
        string $agt[] = eval ($agentCmd);
	rename $agt[0] $aName;

	// Make the vehicle a rigid body with random placement
        float $agentPos[3];
	if (size($placementPattern) == $iNumAgents)
		$agentPos = `xform -q -t $placementPattern[$i-$idxStart]`;
	else 
	{
		$agentPos[0] = rand(-$fCrowdRad,$fCrowdRad) + $fGenCenter[0];
		if ($iCrowdRad2D == 0)
			$agentPos[1] = rand(-$fCrowdRad,$fCrowdRad) + $fGenCenter[1];
		else
			$agentPos[1] = $fGenCenter[1];
		$agentPos[2] = rand(-$fCrowdRad,$fCrowdRad) + $fGenCenter[2];
	}
	// Figure out the object's size along y, so that we can position the agent proxy
	// above and outside the object.
	float $objSize[] = `xform -q -bb $aName`; // Returns [xmin, ymin, zmin, xmax, ymax, zmax]
	//$proxyY = $objSize[4] + ($objSize[4]-$objSize[1])/2.0;
	$proxyY = $agentPos[1];

	// Create a proxy representing the agent, which will be the parent
	// of the duplicated geometry.  Move the pivot of the proxy to the center
	// of the agent itself.
	setupAgentProxy($cName, $agentPos[0], $proxyY, $agentPos[2]);
	move -a $agentPos[0] $agentPos[1] $agentPos[2] $aName;
	move -r 0 ($proxyY - $agentPos[1]) 0 ($aName + ".scalePivot") ($aName + ".rotatePivot");
	parent $aName $cName;

	// Create the debug shapes.
	$r1 = `getAttr ($crowdProxy+".CollisionRadius")`;
	$r2 = `getAttr ($crowdProxy+".ComfortRadius")`;
	$r3 = `getAttr ($crowdProxy+".AwarenessRadius")`;
	$c1 = `circle -c $agentPos[0] $agentPos[1] $agentPos[2] -nr 0 1 0 -sw 360 
			-r $r1 
			-d 3 -ut 0 -tol 0.01 -s 8 -ch 1 
			-n ("CollisionRadius_"+$i)`;
	$c2 = `circle -c $agentPos[0] $agentPos[1] $agentPos[2] -nr 0 1 0 -sw 360 
			-r $r2
			-d 3 -ut 0 -tol 0.01 -s 8 -ch 1 
			-n ("ComfortRadius_"+$i)`;
	$c3 = `circle -c $agentPos[0] $agentPos[1] $agentPos[2] -nr 0 1 0 -sw 360 
			-r $r3
			-d 3 -ut 0 -tol 0.01 -s 8 -ch 1 
			-n ("AwarenessRadius_"+$i)`;
	parent ("CollisionRadius_"+$i) ("ComfortRadius_"+$i) ("AwarenessRadius_"+$i) $cName;
	connectAttr -f ($crowdProxy+".ShowDebugShapes") ("CollisionRadius_"+$i+".visibility");
	connectAttr -f ($crowdProxy+".ShowDebugShapes") ("ComfortRadius_"+$i+".visibility");
	connectAttr -f ($crowdProxy+".ShowDebugShapes") ("AwarenessRadius_"+$i+".visibility");
	connectAttr -f ($crowdProxy+".CollisionRadius") ($c1[1]+".radius");
	connectAttr -f ($crowdProxy+".ComfortRadius") ($c2[1]+".radius");
	connectAttr -f ($crowdProxy+".AwarenessRadius") ($c3[1]+".radius");
	string $attrs[] = {".tx",".ty",".tz",".rx",".ry",".rz",".sx",".sy",".sz"};
	for ($attr in $attrs)
	{
		setAttr -lock true -keyable false ("ComfortRadius_"+$i+$attr);
		setAttr -lock true -keyable false ("CollisionRadius_"+$i+$attr);
		setAttr -lock true -keyable false ("AwarenessRadius_"+$i+$attr);
	}
	setAttr -keyable false ("ComfortRadius_"+$i+".v");
	setAttr -keyable false ("CollisionRadius_"+$i+".v");
	setAttr -keyable false ("AwarenessRadius_"+$i+".v");

        // Create expression for vehicle with a random multiplier
	// added to expression.
    	// connect to goal object
	$expString = "if (" + $crowdProxy + ".EnableProceduralMovement) {\n\n";
    	if ($agentHasGoal == 1)
    	{
		$expString += "// Make the agent follow the goal.\n";
		$expString += "$goalX = " + $agentGoal + ".tx;\n";
		$expString += "$goalY = " + $agentGoal + ".ty;\n";
		$expString += "$goalZ = " + $agentGoal + ".tz;\n";
		$expString += "$dx = $goalX - " + $cName + ".tx;\n";
		$expString += "$dy = $goalY - " + $cName + ".ty;\n";
		$expString += "$dz = $goalZ - " + $cName + ".tz;\n";
		$expString += "$ratio = " + $crowdProxy + ".GoalPriority;\n";
	}
	else
	{
		$expString += "// Randomize direction.\n";
		$expString += "$r1 = rand(-1,1);\n";
		$expString += "$r2 = rand(-1,1);\n\n";
		$expString += "$dx = sin(time*$r1);\n";
		$expString += "$dy = 0.0;\n";
		$expString += "$dz = noise(time*$r1);\n";
		$expString += "$ratio = .5;\n";
	}
	$expString += "$dist = sqrt($dx*$dx + $dy*$dy + $dz*$dz);\n";
	$expString += "if ($dist > " + $crowdProxy + ".MaxAcceleration)\n";
	$expString += "{\n";
	$expString += "  $scale = " + $crowdProxy + ".MaxAcceleration/$dist;\n";
	$expString += "  $dx = $dx * $scale;\n";
	$expString += "  $dy = $dy * $scale;\n";
	$expString += "  $dz = $dz * $scale;\n";
	$expString += "}\n\n";
	$expString += "// Compute forces acting on particles.\n";
	$expString += "float $cf[3]; // Cohesion force\n";
	$expString += "float $sf[3]; // Separation force (comfort zone)\n";
	$expString += "float $af[3]; // Alignment force\n";
	$expString += "float $collf[3];  // Collision force (overrides the others)\n";
	$expString += "int $isColliding = 0;\n";
	$expString += "for ($i = "+$idxStart+"; $i < "+($idxStart+$iNumAgents)+"; $i++)\n";
	$expString += "{\n";
	$expString += "  if ($i != "+$i+" && objExists(\"agentCtrl_\"+$i))\n";
	$expString += "  {\n";
	$expString += "    float $iVec[3];\n";
	$expString += "    $iVec[0] = getAttr(\"agentCtrl_\"+$i+\".tx\") - "+$cName+".translateX;\n";
	$expString += "    $iVec[1] = getAttr(\"agentCtrl_\"+$i+\".ty\") - "+$cName+".translateY;\n";
	$expString += "    $iVec[2] = getAttr(\"agentCtrl_\"+$i+\".tz\") - "+$cName+".translateZ;\n";
	$expString += "    $iDist = sqrt(pow($iVec[0],2)+pow($iVec[1],2)+pow($iVec[2],2));\n\n";
	$expString += "    if ($iDist <= "+$crowdProxy+".AwarenessRadius)\n";
	$expString += "    {\n";
	$expString += "      // Compute cohesion force.\n";
	$expString += "      $cf[0] += $iVec[0]/$iDist;\n";
	$expString += "      $cf[1] += $iVec[1]/$iDist;\n";
	$expString += "      $cf[2] += $iVec[2]/$iDist;\n\n";
	$expString += "      // Compute alignment force.\n";
	$expString += "      float $iVel[3];\n";
	$expString += "      $iVel[0] = getAttr(\"agentCtrl_\"+$i+\".VelX\");\n";
	$expString += "      $iVel[1] = getAttr(\"agentCtrl_\"+$i+\".VelY\");\n";
	$expString += "      $iVel[2] = getAttr(\"agentCtrl_\"+$i+\".VelZ\");\n";
	$expString += "      $iVelMag = sqrt(pow($iVel[0],2)+pow($iVel[1],2)+pow($iVel[2],2));\n";
	$expString += "      if ($iVelMag > 0)\n";
	$expString += "      {\n";
	$expString += "        $af[0] += $iVel[0]/$iVelMag;\n";
	$expString += "        $af[1] += $iVel[1]/$iVelMag;\n";
	$expString += "        $af[2] += $iVel[2]/$iVelMag;\n";
	$expString += "      }\n";
	$expString += "    }\n";
	$expString += "    // Compute separation force.\n";
	$expString += "    if ($iDist <= "+$crowdProxy+".ComfortRadius)\n";
	$expString += "    {\n";
	$expString += "      $sf[0] += -1*$iVec[0]/$iDist;\n";
	$expString += "      $sf[1] += -1*$iVec[1]/$iDist;\n";
	$expString += "      $sf[2] += -1*$iVec[2]/$iDist;\n";
	$expString += "    }\n";
	$expString += "    // Compute collision force.\n";
	$expString += "    if ($iDist <= "+$crowdProxy+".CollisionRadius)\n";
	$expString += "    {\n";
	$expString += "      $isColliding = 1;\n";
	$expString += "      $collf[0] += -1*$iVec[0]/$iDist;\n";
	$expString += "      $collf[1] += -1*$iVec[1]/$iDist;\n";
	$expString += "      $collf[2] += -1*$iVec[2]/$iDist;\n";
	$expString += "    }\n";
	$expString += "  }\n";
	$expString += "}\n";
	$expString += "// Multiply each of the above steering vectors by its priority.\n";
	$expString += "$cf[0] *= "+$crowdProxy+".CohesionPriority;\n";
	$expString += "$cf[1] *= "+$crowdProxy+".CohesionPriority;\n";
	$expString += "$cf[2] *= "+$crowdProxy+".CohesionPriority;\n";
	$expString += "$af[0] *= "+$crowdProxy+".AlignmentPriority;\n";
	$expString += "$af[1] *= "+$crowdProxy+".AlignmentPriority;\n";
	$expString += "$af[2] *= "+$crowdProxy+".AlignmentPriority;\n";
	$expString += "$sf[0] *= "+$crowdProxy+".SeparationPriority;\n";
	$expString += "$sf[1] *= "+$crowdProxy+".SeparationPriority;\n";
	$expString += "$sf[2] *= "+$crowdProxy+".SeparationPriority;\n";
	$expString += "// Put them together.\n";
	$expString += "if ($isColliding)\n";
	$expString += "{\n";
	$expString += "  " + $cName+".VelX += $collf[0];\n";
	$expString += "  " + $cName+".VelY += $collf[1];\n";
	$expString += "  " + $cName+".VelZ += $collf[2];\n";
	$expString += "}\n";
	$expString += "else\n";
	$expString += "{\n";
	$expString += "  " + $cName+".VelX += ($cf[0] + $af[0] + $sf[0])*(1-$ratio)+$dx*$ratio;\n";
	$expString += "  " + $cName+".VelY += ($cf[1] + $af[1] + $sf[1])*(1-$ratio)+$dy*$ratio;\n";
	$expString += "  " + $cName+".VelZ += ($cf[2] + $af[2] + $sf[2])*(1-$ratio)+$dz*$ratio;\n";
	$expString += "}\n\n";
	$expString += "$speed = sqrt(pow("+$cName+".VelX,2) + pow("+$cName+".VelY,2) + pow("+$cName+".VelZ,2));\n";
	$expString += "if ($speed > " + $crowdProxy + ".MaxVelocity)\n";
	$expString += "{\n";
	$expString += "  $scale = "+$crowdProxy+".MaxVelocity/$speed;\n";
	$expString += "  "+$cName+".VelX *= $scale;\n";
	$expString += "  "+$cName+".VelY *= $scale;\n";
	$expString += "  "+$cName+".VelZ *= $scale;\n";
	$expString += "}\n\n";
	$expString += $cName+".translateX += "+$cName+".VelX;\n";
	$expString += "if (" + $crowdProxy + ".Enable3DMovement)\n";
	$expString += "{\n";
	$expString += "  " + $cName+".translateY += "+$cName+".VelY;\n";
	$expString += "}\n";
	$expString += "else\n";
	$expString += "{\n";
	$expString += "  " + $cName+".translateY += 0;\n";
	$expString += "}\n";
	$expString += $cName+".translateZ += "+$cName+".VelZ;\n\n";
	$expString += "// Rotate the agent based on velocity.\n";
	$expString += $cName + ".rotateX = 0;\n";
	$expString += $cName + ".rotateY = ";
	$expString += "atan2d("+$cName+".VelX, "+$cName+".VelZ);\n";
	$expString += $cName + ".rotateZ = 0;\n\n";
	$expString += "}\n";

	expression -s $expString -name ("wander_exp"+$i) -alwaysEvaluate true
                   -unitConversion all;
    } // End agent creation

    // Randomly offset the animation clips.
    // Battle plan: first, go through all the clips in the trax editor,
    // and sort them according to "parent" or "source" animation clip.
    // Then, we generate a random offset per group rather than per clip,
    // ensuring that all clips belonging to a single character have the
    // same offset.  Part of the problem is that MEL doesn't do dynamic
    // 2D arrays (or at least not to my knowledge), so I'm replacing the
    // second dimension by space-separated strings that are tokenized.
    if ($agentHasAnim == 1 && size($agentAnim) > 0 && $fAnimOffsetRange > 0.0)
    {
        // Select all animation clips.
	string $allClips[]; // Its size will be size($agentAnim)-1.
	int $numTokens = -1;
	for ($i=1; $i<size($agentAnim); $i++)
	{
	    // For each of the original animation clips that have been selected,
	    // select all the duplicated versions of that clip.
	    select ($agentAnim[$i] + "*");
	    string $tmpAnims[] = `ls -sl`;
	    // Set numTokens to be the number of such duplicated clips.
	    // If the number mismatches from one set of clips to another,
	    // we raise a warning and pick the smallest of the two values.
	    if ($numTokens == -1)
	        $numTokens = size($tmpAnims);
	    else if ($numTokens != size($tmpAnims))
	    {
	        warning "Mismatch between number of trax clips!";
		$numTokens = ($numTokens < size($tmpAnims) ? $numTokens : size($tmpAnims));
	    }
	    // Since we can't store a 2D array of items, we concatenate
	    // all of the duplicated clips together into a single string
	    // which we will then tokenize later.
	    $allClips[$i-1] = " ";
	    for ($j=0; $j<$numTokens; $j++)
	        $allClips[$i-1] = ($allClips[$i-1] + " " + $tmpAnims[$j]);
	};
	// Now we should have a structure similar to the following:
	//   $allClips[0] = " FootWalk1 FootWalk2 FootWalk3 FootWalk4"
	//   $allClips[1] = " ArmSwing1 ArmSwing2 ArmSwing3 ArmSwing4"
	// The number of tokens in the above example is 4, and the number
	// of distinct clips is 2.  For each of the 4 tokens, we decide
	// a random clip offset, tokenize each of the strings, and
	// apply that offset to all tokens at the same index in the sequence.
	// For example, we might apply an offset of 10 frames to clips
	// FootWalk2 and ArmSwing2 during the second iteration through the
	// outer loop.
	for ($i=0; $i<$numTokens; $i++)
	{
	    // Pick a random offset value.
	    $offset = rand(0, $fAnimOffsetRange);
	    // Pick a random scale value related to specified velocities.
	    float $fScale = rand(1,$fAnimSpeedRange);
	    for ($j=0; $j<size($allClips); $j++)
	    {
	        string $tokens[];
		tokenize($allClips[$j], $tokens);
	        $clip = $tokens[$i];
		$clipEnd = `getAttr ($clip+".sourceEnd")`;
		$clipStart = `getAttr ($clip+".sourceStart")`;
		$clipOffset = (int)($offset*($clipEnd-$clipStart));
		setAttr ($clip + ".startFrame") $clipOffset;
		$fOldScale = `getAttr ($clip + ".scale")`;
		setAttr ($clip + ".scale") ($fScale*$fOldScale);
	    }
	}
    }

    cycleCheck -e off;

} // End createCrowd

global proc collectObstacles()
{
    // Redeclare the global variable.
    global string $collectObstaclesField;
    global string $collectObjects[];
    $collectObjects = `ls -sl`;
    //string $collectCurrObjects[] = `ls -sl`;
    if (size($collectObjects) == 0)
    {
        print "Clearing previously selected objects.\n";
	textFieldButtonGrp -edit -text "(None selected)" $collectObstaclesField;
    }
    else
    {
	//int $iNumExistingObjects = size($collectObjects);
     	string $objectsTxt = "";
        for ($i=0; $i < size($collectObjects); $i++)
        {
            rigidBody -passive
	              -name ($collectObjects[$i] + "RigidB" + $i)
		      -bounciness 2.0
		      ($collectObjects[$i]);
	    //$collectObjects[$iNumExistingObjects+$i] = $collectObjects[$i];
	    $objectsTxt += $collectObjects[$i];
	    $objectsTxt += ($i == size($collectObjects)-1) ? "" : ", ";
        }
	textFieldButtonGrp -edit -text $objectsTxt $collectObstaclesField;
    }
} // End collectObstacles

// Create a low-poly sphere outline as the center object.
// Do not call this method directly - it's used by createCrowdSystemProxy.
proc makeCrowdSystemProxy(string $name)
{
    global string $crowdSystemProxy = "";
    $crowdSystemProxy = `curve -d 1 -p 0 1 0 -p -0.353553 0.707107 -0.612373 -p -0.707107 0.707107 -1.12324e-007 -p -0.353553 0.707107 0.612372 -p 0.353553 0.707107 0.612372 -p 0.707107 0.707107 0 -p 0.353554 0.707107 -0.612372 -p -0.353553 0.707107 -0.612373 -p -0.5 0 -0.866026 -p -1 0 -1.5885e-007 -p -0.5 0 0.866025 -p 0.5 0 0.866025 -p 1 0 0 -p 0.5 0 -0.866025 -p -0.5 0 -0.866026 -p -0.353553 -0.707107 -0.612373 -p -0.707107 -0.707107 -1.12324e-007 -p -0.353553 -0.707107 0.612372 -p 0.353553 -0.707107 0.612372 -p 0.707107 -0.707107 0 -p 0.353554 -0.707107 -0.612372 -p -0.353553 -0.707107 -0.612373 -p 0 -1 0 -p 0.353554 -0.707107 -0.612372 -p 0.5 0 -0.866025 -p 0.353554 0.707107 -0.612372 -p 0 1 0 -p 0.707107 0.707107 0 -p 1 0 0 -p 0.707107 -0.707107 0 -p 0 -1 0 -p 0.353553 -0.707107 0.612372 -p 0.5 0 0.866025 -p 0.353553 0.707107 0.612372 -p 0 1 0 -p -0.353553 0.707107 0.612372 -p -0.5 0 0.866025 -p -0.353553 -0.707107 0.612372 -p 0 -1 0 -p -0.707107 -0.707107 -1.12324e-007 -p -1 0 -1.5885e-007 -p -0.707107 0.707107 -1.12324e-007 -p 0 1 0 -k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 -k 16 -k 17 -k 18 -k 19 -k 20 -k 21 -k 22 -k 23 -k 24 -k 25 -k 26 -k 27 -k 28 -k 29 -k 30 -k 31 -k 32 -k 33 -k 34 -k 35 -k 36 -k 37 -k 38 -k 39 -k 40 -k 41 -k 42 -n $name`;
}

// Create a triangle to represent each agent.
// Do not call this method directly - it's used by createAgentProxy.
proc makeAgentProxy(string $proxyName)
{
    curve -d 1 -p -1 0 -1 -p 2 0 0 -p -1 0 1 -p -1 0 -1 -k 0 -k 1 -k 2 -k 3 -n $proxyName;
}

// This creates the geometry shape and sets up all the attributes.
global proc string setupCrowdSystemProxy()
{
    // Import the variables we'll be setting.
    global float $fMaxVelocity;
    global float $fMaxAcceleration;
    global float $fSeparationPriority;
    global float $fCohesionPriority;
    global float $fAlignmentPriority;
    global float $fGoalPriority;
    global float $fCollisionRadius;
    global float $fComfortRadius;
    global float $fAwarenessRadius;
    global int $debugShapes;
    global int $enableMovement;
    global int $yAxisActive;

    // Determine name
    string $basename = "CrowdSystemCtrl";
    string $name = $basename;
    int $nameIdx = 1;
    while (`objExists $name`)
        $name = ($basename + $nameIdx);
    makeCrowdSystemProxy($name);

    // Lock and hide rotation & visibility attributes.
    setAttr -lock true -keyable false ($name + ".rx");
    setAttr -lock true -keyable false ($name + ".ry");
    setAttr -lock true -keyable false ($name + ".rz");
    setAttr -lock true -keyable false ($name + ".v");

    // Hide scale and replace it with a single attribute.
    setAttr -keyable false ($name + ".sx");
    setAttr -keyable false ($name + ".sy");
    setAttr -keyable false ($name + ".sz");
    addAttr -ln Scale -at double  -dv 1 $name;
    setAttr -e -keyable true ($name + ".Scale");
    expression -s ($name + ".scaleX = " + $name + ".Scale;\r\n " +
	$name + ".scaleY = " + $name + ".Scale;\r\n " +
	$name + ".scaleZ = " + $name + ".Scale;") 
	-o $name -ae 1 -uc all ;

    // Add procedural movement attr
    addAttr -ln EnableProceduralMovement -at bool $name;
    setAttr -e -keyable true ($name + ".EnableProceduralMovement");
    setAttr ($name + ".EnableProceduralMovement") $enableMovement;

    // Add procedural movement attr
    addAttr -ln Enable3DMovement -at bool $name;
    setAttr -e -keyable true ($name + ".Enable3DMovement");
    setAttr ($name + ".Enable3DMovement") $yAxisActive;

    // Add max velocity attr
    addAttr -ln MaxVelocity -at double  -min 0 $name;
    setAttr -e -keyable true ($name + ".MaxVelocity");
    setAttr ($name + ".MaxVelocity") $fMaxVelocity;

    // Add max accel attr
    addAttr -ln MaxAcceleration -at double  -min 0 $name;
    setAttr -e -keyable true ($name + ".MaxAcceleration");
    setAttr ($name + ".MaxAcceleration") $fMaxAcceleration;

    // Add separation priority attr
    addAttr -ln SeparationPriority -at double  -min 0 -max 1 $name;
    setAttr -e -keyable true ($name + ".SeparationPriority");
    setAttr ($name + ".SeparationPriority") $fSeparationPriority;

    // Add cohesion priority attr
    addAttr -ln CohesionPriority -at double  -min 0 -max 1 $name;
    setAttr -e -keyable true ($name + ".CohesionPriority");
    setAttr ($name + ".CohesionPriority") $fCohesionPriority;

    // Add alignment priority attr
    addAttr -ln AlignmentPriority -at double  -min 0 -max 1 $name;
    setAttr -e -keyable true ($name + ".AlignmentPriority");
    setAttr ($name + ".AlignmentPriority") $fAlignmentPriority;

    // Add goal priority attr
    addAttr -ln GoalPriority -at double  -min 0 -max 1 $name;
    setAttr -e -keyable true ($name + ".GoalPriority");
    setAttr ($name + ".GoalPriority") $fGoalPriority;

    // Add collision radius attr
    addAttr -ln CollisionRadius -at double  -min 0 $name;
    setAttr -e -keyable true ($name + ".CollisionRadius");
    setAttr ($name + ".CollisionRadius") $fCollisionRadius;

    // Add comfort radius attr
    addAttr -ln ComfortRadius -at double  -min 0 $name;
    setAttr -e -keyable true ($name + ".ComfortRadius");
    setAttr ($name + ".ComfortRadius") $fComfortRadius;

    // Add awareness radius attr
    addAttr -ln AwarenessRadius -at double  -min 0 $name;
    setAttr -e -keyable true ($name + ".AwarenessRadius");
    setAttr ($name + ".AwarenessRadius") $fAwarenessRadius;

    // Add debug shapes attr
    addAttr -ln ShowDebugShapes -at bool $name;
    setAttr -e -keyable true ($name + ".ShowDebugShapes");
    setAttr ($name + ".ShowDebugShapes") $debugShapes;

    return $name;
}

global proc setupAgentProxy(string $name, float $posX, float $posY, float $posZ)
{
    // Create the proxy object
    makeAgentProxy($name);
    move -r $posX $posY $posZ $name;
    rotate -r 0 -90 0 $name;
    makeIdentity -apply true -t 0 -r 1 -s 1 -n 0 $name;

    // Add velocity attr
    addAttr -ln Vel -at double3 $name;
    addAttr -ln VelX -at double -p Vel $name;
    addAttr -ln VelY -at double -p Vel $name;
    addAttr -ln VelZ -at double -p Vel $name;
    setAttr -type double3 ($name + ".Vel") 0 0 0;
    setAttr -e -keyable true ($name + ".Vel");
    setAttr -e -keyable true ($name + ".VelX");
    setAttr -e -keyable true ($name + ".VelY");
    setAttr -e -keyable true ($name + ".VelZ");

}

global proc setAgentModel()
{
    global string $agentModel;
    global string $agentModelField;
    global string $agentModelNameField;
    string $agentModels[] = `ls -sl`;
    if (size($agentModels) != 1)
    {
        error "Please select only one object as the agent model.\n";
    }
    else
    {
        $agentModel = $agentModels[0];
	//print ($agentModel + "\n");
	textFieldButtonGrp -edit -text $agentModel $agentModelField;
    	nameField -edit -object $agentModel $agentModelNameField;
	//setAgentColl;
    }
}  // End setAgentModel

global proc setAgentCharSet()
{
    global string $agentCharSet;
    global string $agentCharSetField;
    global string $agentCharSetNameField;
    string $charSets[] = `ls -sl`;
    if (size($charSets) != 1)
        error "Please select only one character set.\n";
    else
    {
        $agentCharSet = $charSets[0];
	textFieldButtonGrp -edit -text $agentCharSet $agentCharSetField;
    	nameField -edit -object $agentCharSet $agentCharSetNameField;
    }
} // End setAgentCharSet

global proc setAgentAnim()
{
    global string $agentAnim[];
    global string $agentAnimField;
    global string $agentAnimNameFields[];
    clear $agentAnimNameFields;	// Reset the values inside the array.
    string $charAnims[] = `ls -sl`;
    if (size($charAnims) < 2)
        error "Please select at least one trax clip.\n";
    else
    {
        // Copy the first entry (charset) without any changes.
        $agentAnim[0] = $charAnims[0];
	string $fieldTxt = $agentAnim[0] + ":";
	for ($i=1; $i<size($charAnims); $i++)
	{
            $agentAnim[$i] = $charAnims[$i];
	    // Remove any numbers at the end.
	    $agentAnim[$i] = `match "^[a-zA-Z][a-zA-Z0-9_]*[a-zA-Z_]+" $agentAnim[$i]`;
	    $fieldTxt += (" " + $agentAnim[$i]);
    	    $agentAnimNameFields[$i] = `nameField -visible 0
		-object $agentAnim[$i]
		-ncc "for(int $ii=0;$ii<size($agentAnimNameFields);$ii++){ \
			$tmpChangedName=`nameField -q -o $agentAnimNameFields[$ii]`; \
		      	select -add $tmpChangedName;} \
			setAgentAnim; select -cl;"`;
	}
	textFieldButtonGrp -edit -text $fieldTxt $agentAnimField;
    }
} // End setAgentAnim

global proc setAgentSkin()
{
    global string $agentSkin;
    global string $agentSkinField;
    string $charSkins[] = `ls -sl`;
    if (size($charSkins) != 1)
        error "Please select only one skin.\n";
    else
    {
        $agentSkin = $charSkins[0];
	textFieldButtonGrp -edit -text $agentSkin $agentSkinField;
    }
} // End setAgentSkin

/*
global proc setAgentColl()
{
    global float $agentCollRadius;
    global string $agentCollField;
    string $charColls[] = `ls -sl`;
    if (size($charColls) != 1)
        error "Please select only one collision solid.\n";
    else
    {
        // Since this could be any object, it is safest to use its bounding box
	// and take its largest dimension as the radius of the collision sphere.
        float $bb[] = `xform -q -bb $charColls[0]`;
	float $bbRadius = `max ($bb[4]-$bb[1]) ($bb[5]-$bb[2])`;
	$bbRadius = `max ($bb[3]-$bb[0]) $bbRadius`;
	float $agentCollRadius = $bbRadius / 2.0;
	textFieldButtonGrp -edit -text ("Approx. radius = " + $agentCollRadius) $agentCollField;
    }
} // End setAgentColl
*/

global proc setAgentGoal()
{
    global string $agentGoal;
    global string $agentGoalField;
    global string $agentGoalNameField;
    string $charGoals[] = `ls -sl`;
    if (size($charGoals) != 1)
        error "Please select only one goal.\n";
    else
    {
        $agentGoal = $charGoals[0];
	textFieldButtonGrp -edit -text $agentGoal $agentGoalField;
    	nameField -edit -object $agentGoal $agentGoalNameField;
    }
} // End setAgentGoal

global proc importPositionPattern()
{
    global string $placementPatternButton;
    global int $iNumAgents;
    global string $placementPattern[];
    $placementPattern = `ls -sl`;
    if (size($placementPattern) != $iNumAgents)
        error ("Number of positions ("+size($placementPattern)+") must match number of agents ("+$iNumAgents+")!\n");
    else
    {
	string $objectsTxt = "";
        for ($i=0; $i < size($placementPattern); $i++)
        {
	    float $pppos[] = `xform -q -t $placementPattern[$i]`;
	    for ($j=0; $j<3; $j++) {
		$pppos[$j] = `trunc ($pppos[$j]*1000.0)`;
		$pppos[$j] = $pppos[$j]/1000.0;
	    }
	    $objectsTxt += ("("+$pppos[0]+", "+$pppos[1]+", "+$pppos[2]+")");
	    $objectsTxt += ($i == size($placementPattern)-1) ? "" : ", ";
        }
	textFieldButtonGrp -edit -text $objectsTxt $placementPatternButton;
    }
} // End importPositionPattern

global proc enableRandomPlacementUI()
{
    global string $placementPosGrp;
    global string $crowdRadField;
    global string $crowdRad2DField;
    global string $placementPatternButton;
    floatFieldGrp -e -enable 1 $placementPosGrp;
    floatFieldGrp -e -enable 1 $crowdRadField;
    checkBoxGrp   -e -enable 1 $crowdRad2DField;
    textFieldButtonGrp -e -enable 0 $placementPatternButton;
}

global proc enablePatternPlacementUI()
{
    global string $placementPosGrp;
    global string $crowdRadField;
    global string $crowdRad2DField;
    global string $placementPatternButton;
    floatFieldGrp -e -enable 0 $placementPosGrp;
    floatFieldGrp -e -enable 0 $crowdRadField;
    checkBoxGrp   -e -enable 0 $crowdRad2DField;
    textFieldButtonGrp -e -enable 1 $placementPatternButton;
    textFieldButtonGrp -e -editable 0 $placementPatternButton;
}

global proc enableAnimation()
{
    global int $agentHasAnim;
    global string $agentCharSetField;
    global string $agentAnimField;
    $agentHasAnim = 1;
    textFieldButtonGrp -edit -enable 1 $agentCharSetField;
    textFieldButtonGrp -edit -enable 1 $agentAnimField;
    textFieldButtonGrp -edit -editable 0 $agentCharSetField;
    textFieldButtonGrp -edit -editable 0 $agentAnimField;
}

global proc disableAnimation()
{
    global int $agentHasAnim;
    global string $agentCharSetField;
    global string $agentAnimField;
    $agentHasAnim = 0;
    textFieldButtonGrp -edit -enable 0 $agentCharSetField;
    textFieldButtonGrp -edit -enable 0 $agentAnimField;
}

global proc enableGoal()
{
    global int $agentHasGoal;
    global string $agentGoalField;
    global string $goalPriorityGrp;
    $agentHasGoal = 1;
    textFieldButtonGrp -edit -enable 1 $agentGoalField;
    floatSliderGrp -edit -enable 1 $goalPriorityGrp;
    textFieldButtonGrp -edit -editable 0 $agentGoalField;
}

global proc disableGoal()
{
    global int $agentHasGoal;
    global string $agentGoalField;
    global string $goalPriorityGrp;
    $agentHasGoal = 0;
    textFieldButtonGrp -edit -enable 0 $agentGoalField;
    floatSliderGrp -edit -enable 0 $goalPriorityGrp;
}

global proc disableProceduralMovement()
{
    global int $enableMovement;
    global string $maxVelocityGrp;
    global string $maxAccelerationGrp;
    global string $separationPriorityGrp;
    global string $cohesionPriorityGrp;
    global string $alignmentPriorityGrp;
    global string $collisionRadiusField;
    global string $awarenessRadiusField;
    global string $comfortRadiusField;
    global string $debugShapesField;
    global string $fomGrp;

    $enableMovement = 0;
    floatSliderGrp -e -enable 0 $maxVelocityGrp;
    floatSliderGrp -e -enable 0 $maxAccelerationGrp;
    floatSliderGrp -e -enable 0 $separationPriorityGrp;
    floatSliderGrp -e -enable 0 $cohesionPriorityGrp;
    floatSliderGrp -e -enable 0 $alignmentPriorityGrp;
    floatFieldGrp -e -enable 0 $collisionRadiusField;
    floatFieldGrp -e -enable 0 $comfortRadiusField;
    floatFieldGrp -e -enable 0 $awarenessRadiusField;
    checkBoxGrp -e -enable 0 $debugShapesField;
    radioButtonGrp -e -enable 0 $fomGrp;
}

global proc enableProceduralMovement()
{
    global int $enableMovement;
    global string $maxVelocityGrp;
    global string $maxAccelerationGrp;
    global string $separationPriorityGrp;
    global string $cohesionPriorityGrp;
    global string $alignmentPriorityGrp;
    global string $collisionRadiusField;
    global string $awarenessRadiusField;
    global string $comfortRadiusField;
    global string $debugShapesField;
    global string $fomGrp;

    $enableMovement = 1;
    floatSliderGrp -e -enable 1 $maxVelocityGrp;
    floatSliderGrp -e -enable 1 $maxAccelerationGrp;
    floatSliderGrp -e -enable 1 $separationPriorityGrp;
    floatSliderGrp -e -enable 1 $cohesionPriorityGrp;
    floatSliderGrp -e -enable 1 $alignmentPriorityGrp;
    floatFieldGrp -e -enable 1 $collisionRadiusField;
    floatFieldGrp -e -enable 1 $comfortRadiusField;
    floatFieldGrp -e -enable 1 $awarenessRadiusField;
    checkBoxGrp -e -enable 1 $debugShapesField;
    radioButtonGrp -e -enable 1 $fomGrp;
}

global proc priorityDragCallback(int $sliderNum)
{
    global float $fSeparationPriority;
    global float $fCohesionPriority;
    global float $fAlignmentPriority;
    global string $separationPriorityGrp;
    global string $cohesionPriorityGrp;
    global string $alignmentPriorityGrp;
    float $scale;

    if ($sliderNum == 0) // Dragging the separation priority bar
    {
	$fSeparationPriority=`floatSliderGrp -q -v $separationPriorityGrp`;
	if ($fAlignmentPriority+$fCohesionPriority == 0)
	{
		$scale=(1.0-$fSeparationPriority)/2.0;
		$fAlignmentPriority = 0.001;
		$fCohesionPriority = 0.001;
	}
	else
		$scale=(1.0-$fSeparationPriority)/($fAlignmentPriority+$fCohesionPriority);
	$fCohesionPriority *= $scale;
	$fAlignmentPriority *= $scale;
	floatSliderGrp -e -v $fCohesionPriority $cohesionPriorityGrp;
	floatSliderGrp -e -v $fAlignmentPriority $alignmentPriorityGrp;
    }
    else if ($sliderNum == 1) // Dragging the cohesion priority bar
    {
	$fCohesionPriority=`floatSliderGrp -q -v $cohesionPriorityGrp`;
	if ($fAlignmentPriority+$fSeparationPriority == 0)
	{
		$scale=(1.0-$fCohesionPriority)/2.0;
		$fAlignmentPriority = 0.001;
		$fSeparationPriority = 0.001;
	}
	else
		$scale=(1.0-$fCohesionPriority)/($fAlignmentPriority+$fSeparationPriority);
	$fSeparationPriority *= $scale;
	$fAlignmentPriority *= $scale;
	floatSliderGrp -e -v $fSeparationPriority $separationPriorityGrp;
	floatSliderGrp -e -v $fAlignmentPriority $alignmentPriorityGrp;
    }
    else // Dragging the alignment bar
    {
	$fAlignmentPriority=`floatSliderGrp -q -v $alignmentPriorityGrp`;
	if ($fSeparationPriority+$fCohesionPriority == 0)
	{	
		$scale=(1.0-$fAlignmentPriority)/2.0;
		$fSeparationPriority = 0.001;
		$fCohesionPriority = 0.001;
	}
	else
		$scale=(1.0-$fAlignmentPriority)/($fSeparationPriority+$fCohesionPriority);
	$fSeparationPriority *= $scale;
	$fCohesionPriority *= $scale;
	floatSliderGrp -e -v $fSeparationPriority $separationPriorityGrp;
	floatSliderGrp -e -v $fCohesionPriority $cohesionPriorityGrp;
    }
}


// Create the interface
global proc crowdUISetup()
{
    // Initialize global variables (will be queried from interface later)
    global string $numAgentsGrp;
    global string $crowdRadField;
    global string $agentModelField;
    global string $agentCharSetField;
    global string $agentAnimField;
    global string $agentSkinField;
    global string $agentCollField;
    global string $agentGoalField;
    global string $placementPosGrp;
    global string $crowdRadField;
    global string $crowdRad2DField;
    global string $placementPatternButton;
    //global string $collectObstaclesField;
    global string $animSpeedRangeGrp;
    global string $animOffsetRangeGrp;
    //global string $massMinMaxField;
    // These will most likely never be used, but they are a good safety measure.
    // Whenever an object is selected, it is attached to a nameField, so that
    // if its name changes, the change is propagated to the variable 
    // storing that object.
    global string $agentModelNameField;
    global string $agentCharSetNameField;
    global string $agentAnimNameFields[];
    global string $agentGoalNameField;
    
    global int $agentHasAnim = 0;
    global int $agentHasGoal = 0;
    global float $fCrowdRad = 40.0;
    global float $fImpulseRange = 3.0;
    global int $iNumAgents = 10;
    global float $fAnimOffsetRange = 1.0;  // Between 0 and 1 inclusive.
    global float $fAnimSpeedRange = 2.0;   // 1 = no variation, 2 = up to 100% variation, etc.
    global int $iCrowdRad2D = 1;
    global float $fGenCenter[];
    //global int $collideWithPriorAgents = 1;

    //global float $fMassMin = 1.0;
    //global float $fMassMax = 5.0;
    global int $yAxisActive = 0;
    //global int $gforces = 0;

    global float $fMaxVelocity = 1;
    global float $fMaxAcceleration = .5;
    global float $fSeparationPriority = .5;
    global float $fCohesionPriority = .3;
    global float $fAlignmentPriority = .2;
    global float $fGoalPriority = .5;
    global float $fCollisionRadius = 1.0;
    global float $fComfortRadius = 5.0;
    global float $fAwarenessRadius = 30.0;
    global int $debugShapes = 1;
    global int $enableMovement = 1;
    

    window
       -title "Crowd System"
       -widthHeight 400 300
       crowdWin;
       
    // Define the layout for this window.
    $optLayout = getOptionBox();
    setOptionBoxCommandName("createCrowd");
    setOptionBoxTitle("Create Crowd System");

    setParent $optLayout;
    scrollLayout -horizontalScrollBarThickness 0 -childResizable 1;
    string $topLayout = `columnLayout -adjustableColumn 1 -rs 2`;

    // Frame for agent creation
    frameLayout -label "Agent Creation" 
		-borderStyle "etchedIn" 
		-collapsable 1;
    columnLayout -adjustableColumn 1 -columnAttach "left" 0;

    // Create the int slider for specifying the number of agents.
    $numAgentsGrp = `intSliderGrp -min 1 -max 30 
				  -fieldMinValue 1
				  -field true
				  //-columnWidth 1 130
				  //-columnWidth 2 70
				  //-columnWidth 3 30
                                  -label "Number of Agents"`;
    // When sliders are dragged, set the corresponding int value.
    // Note: -cc is shorthand for -changeCommand.
    intSliderGrp -edit -cc "$iNumAgents=`intSliderGrp -q -v $numAgentsGrp`"
		 $numAgentsGrp;
    intSliderGrp -edit -value $iNumAgents $numAgentsGrp;
    separator -height 10;

    // Create the placement interface
    $placementGrp = `radioButtonGrp -numberOfRadioButtons 2
				-label "Placement"
				-labelArray2 "Random" "Existing Pattern"
				-select 1
				-onCommand1 enableRandomPlacementUI
				-onCommand2 enablePatternPlacementUI`;
    // Create position interface for random placement
    $placementPosGrp = `floatFieldGrp -numberOfFields 3
				-label "Center"
				-value1 0.0 -value2 0.0 -value3 0.0
				-changeCommand "$fGenCenter[0]=`floatFieldGrp -q -v1 $placementPosGrp`;\
						$fGenCenter[1]=`floatFieldGrp -q -v2 $placementPosGrp`;\
						$fGenCenter[2]=`floatFieldGrp -q -v3 $placementPosGrp`;"`;
    // Create radius interface for random placement
    $crowdRadField = `floatFieldGrp -numberOfFields 1
				-label "Radius"
				-value1 40.0
				-changeCommand "$fCrowdRad=`floatFieldGrp -q -v1 $crowdRadField`"`;
    $crowdRad2DField = `checkBoxGrp -numberOfCheckBoxes 1
				-label ""
				-label1 "Vertical Displacement"
				-columnWidth 2 150
				-onCommand1 "$iCrowdRad2D=0"
				-offCommand1 "$iCrowdRad2D=1"`;
    // Create pattern setting interface for patter placement
    $placementPatternButton = `textFieldButtonGrp -buttonLabel "Import Positions"
				-label ""
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				//-columnAttach 3 "left" 0
				-buttonCommand importPositionPattern`;
    // Need to run the placement type command AFTER all the UI has been added.
    enableRandomPlacementUI;

    setParent $topLayout;


    // Frame for agent model, etc.
    frameLayout -label "Agent Geometry and Behavior" 
		-borderStyle "etchedIn" 
		-collapsable 1;
    columnLayout -adjustableColumn 1 -columnAttach "left" 0;

    // Field to select the model/skeleton of the agent.
    $agentModelField = `textFieldButtonGrp -label "Model or Skeleton"
				-buttonLabel "Set Model"
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				-buttonCommand setAgentModel`;
    $agentModelNameField = `nameField -visible 0
		-ncc "$tmpChangedName=`nameField -q -o $agentModelNameField`; \
		      select $tmpChangedName; setAgentModel; select -cl;"`;

    // Field to select the collision solid.
//    $agentCollField = `textFieldButtonGrp -label "Custom Collision Solid"
//				-buttonLabel "Set Collision"
//				-editable 0
//				-text "(None selected)"
//				-columnWidth 2 150
//				-buttonCommand setAgentColl`;

    separator -height 10;

    // Set up animation interface
    $hasAnimField = `checkBoxGrp -numberOfCheckBoxes 1
				-label ""
				-label1 "Has Animation"
				-columnWidth 2 150
				-onCommand1 enableAnimation
				-offCommand1 disableAnimation`;
    // Field to select the character set.
    $agentCharSetField = `textFieldButtonGrp -label "Character Set"
				-buttonLabel "Set CharSet"
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				-buttonCommand setAgentCharSet`;
    $agentCharSetNameField = `nameField -visible 0
		-ncc "$tmpChangedName=`nameField -q -o $agentCharSetNameField`; \
		      select $tmpChangedName; setAgentCharSet; select -cl;"`;
    // Field to select the character animations.
    $agentAnimField = `textFieldButtonGrp -label "Animation"
				-buttonLabel "Set Clip(s)"
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				-buttonCommand setAgentAnim`;
    disableAnimation;

    separator -height 10;

    // Set up goal following interface
    $hasGoalField = `checkBoxGrp -numberOfCheckBoxes 1
				-label ""
				-label1 "Follows Goal"
				-columnWidth 2 150
				-onCommand1 enableGoal
				-offCommand1 disableGoal`;
    $agentGoalField  = `textFieldButtonGrp -label "Goal"
				-buttonLabel "Set Goal"
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				-buttonCommand setAgentGoal`;
    global string $goalPriorityGrp;
    $goalPriorityGrp = `floatSliderGrp -min 0 -max 1
			-fieldMinValue 0 -fieldMaxValue 1
			-field true
			-step 0.01
			-value $fGoalPriority
			-label "Goal Priority"`;
    floatSliderGrp -e -cc "$fGoalPriority=`floatSliderGrp -q -v $goalPriorityGrp`" $goalPriorityGrp;
    $agentGoalNameField = `nameField -visible 0
		-ncc "$tmpChangedName=`nameField -q -o $agentGoalNameField`; \
		      select $tmpChangedName; setAgentGoal; select -cl;"`;
    disableGoal;

    setParent $topLayout;



    // Frame for movement options.
    frameLayout -label "Movement"
		-borderStyle "etchedIn"
		-collapsable 1
		-collapse 0;
    columnLayout -adjustableColumn 1 -columnAttach "both" 0;
	
    // Create interface for movement enabling.
    $enableMovementField = `checkBoxGrp -numberOfCheckBoxes 1
			-label ""
			-value1 1
			-label1 "Enable procedural movement"
			-columnWidth 2 250
			-onCommand1 "enableProceduralMovement"
			-offCommand1 "disableProceduralMovement"`;

    // Create interface for velocity.
    global string $maxVelocityGrp = "";
    global string $maxAccelerationGrp = "";

    $maxVelocityGrp = `floatSliderGrp -min 0 -max 100
			-fieldMinValue 0
			-field true
			-value $fMaxVelocity
			-label "Max Velocity"`;
    floatSliderGrp -e -cc "$fMaxVelocity=`floatSliderGrp -q -v $maxVelocityGrp`" $maxVelocityGrp;

    // Create interface for acceleration.
    $maxAccelerationGrp = `floatSliderGrp -min 0 -max 10
			-fieldMinValue 0
			-field true
			-value $fMaxAcceleration
			-label "Max Acceleration"`;
    floatSliderGrp -e -cc "$fMaxAcceleration=`floatSliderGrp -q -v $maxAccelerationGrp`"
		$maxAccelerationGrp;

    // Create the 2D vs. 3D freedom of movement interface
    global string $fomGrp = "";
    $fomGrp = `radioButtonGrp -label "Freedom of Movement"
			      	-numberOfRadioButtons 2
			      	-labelArray2 "2D" "3D"
			      	-select 1
			      	-onCommand1 "$yAxisActive=0"
  			      	-onCommand2 "$yAxisActive=1"`;

    separator -height 10;

    // Set up label for the priorities.
    rowLayout -cw2 140 250 -nc 2;
	text -label "";
        text -label "The following priorities must add up to 1." -align "left";
        setParent ..;

    global string $separationPriorityGrp = "";
    global string $cohesionPriorityGrp = "";
    global string $alignmentPriorityGrp = "";

    // Set up the sliders for priorities.
    $separationPriorityGrp = `floatSliderGrp -min 0 -max 1
			-fieldMinValue 0 -fieldMaxValue 1
			-field true
			-step 0.01
			-value $fSeparationPriority
			-label "Separation Priority"`;
    $cohesionPriorityGrp = `floatSliderGrp -min 0 -max 1
			-fieldMinValue 0 -fieldMaxValue 1
			-field true
			-step 0.01
			-value $fCohesionPriority
			-label "Cohesion Priority"`;
    $alignmentPriorityGrp = `floatSliderGrp -min 0 -max 1
			-fieldMinValue 0 -fieldMaxValue 1
			-field true
			-step 0.01
			-value $fAlignmentPriority
			-label "Alignment Priority"`;
    floatSliderGrp -e -dc "priorityDragCallback(0)" -cc "priorityDragCallback(0)" $separationPriorityGrp;
    floatSliderGrp -e -dc "priorityDragCallback(1)" -cc "priorityDragCallback(1)" $cohesionPriorityGrp;
    floatSliderGrp -e -dc "priorityDragCallback(2)" -cc "priorityDragCallback(2)" $alignmentPriorityGrp;
    separator -height 10;

    // Set up label for the radius fields.
    rowLayout -cw2 140 250 -nc 2;
	text -label "";
        text -label "Collision radius cannot be greater than awareness radius." -align "left";
        setParent ..;

    // Create collision and awareness radius interfaces
    global string $collisionRadiusField = "";
    global string $awarenessRadiusField = "";
    global string $comfortRadiusField = "";
    $collisionRadiusField = `floatFieldGrp -numberOfFields 1
			-label "Collision Radius"
			-value1 $fCollisionRadius`;
    $comfortRadiusField = `floatFieldGrp -numberOfFields 1
			-label "Comfort Zone Radius"
			-value1 $fComfortRadius`;
    $awarenessRadiusField = `floatFieldGrp -numberOfFields 1
			-label "Awareness Radius"
			-value1 $fAwarenessRadius`;
    floatFieldGrp -edit -cc "$fCollisionRadius=`floatFieldGrp -q -v1 $collisionRadiusField`; \
			$fCollisionRadius=min($fAwarenessRadius,$fCollisionRadius); \
			$fCollisionRadius=min($fComfortRadius,$fCollisionRadius); \
			floatFieldGrp -e -v1 $fCollisionRadius $collisionRadiusField;"
		 	$collisionRadiusField;
    floatFieldGrp -edit -cc "$fComfortRadius=`floatFieldGrp -q -v1 $comfortRadiusField`; \
			$fComfortRadius=max($fCollisionRadius,$fComfortRadius); \
			$fComfortRadius=min($fAwarenessRadius,$fComfortRadius); \
			floatFieldGrp -e -v1 $fComfortRadius $comfortRadiusField;"
		 	$comfortRadiusField;
    floatFieldGrp -edit -cc "$fAwarenessRadius=`floatFieldGrp -q -v1 $awarenessRadiusField`; \
			$fAwarenessRadius=max($fAwarenessRadius,$fCollisionRadius); \
			$fAwarenessRadius=max($fAwarenessRadius,$fComfortRadius); \
			floatFieldGrp -e -v1 $fAwarenessRadius $awarenessRadiusField;"
		 	$awarenessRadiusField;
    separator -height 10;

    // Create a check box for debug shapes.
    global string $debugShapesField = "";
    $debugShapesField = `checkBoxGrp -numberOfCheckBoxes 1
			-label ""
			-value1 $debugShapes
			-label1 "Show debug shapes"
			-columnWidth 2 250
			-onCommand1 "$debugShapes=1"
			-offCommand1 "$debugShapes=0"`;    

    setParent $topLayout;

    // Now that all the interface has been created, enable it.
    enableProceduralMovement;


    // Frame for advanced options
    frameLayout -label "Advanced Options" 
		-borderStyle "etchedIn" 
		-collapsable 1
		-collapse 1;
    columnLayout -adjustableColumn 1 -columnAttach "both" 0;

    // Create mass interface.
//    $massMinMaxField = `floatFieldGrp -numberOfFields 2
//				-label "Mass Min/Max"
//				-value1 1.0 -value2 5.0`;
//    floatFieldGrp -edit -cc "$fMassMin=`floatFieldGrp -q -v1 $massMinMaxField`; \
//			     $fMassMax=`floatFieldGrp -q -v2 $massMinMaxField`;"
//		 $massMinMaxField;
//    separator -height 10;

    // Create the float slider for specifying the animation speed variation.
    $animSpeedRangeGrp = `floatSliderGrp -min 1 -max 2
				-fieldMinValue 0
				//-fieldMaxValue 3
				-field true
				-value 2
                                -label "Animation Speed Variation"`;
    floatSliderGrp -edit -cc "$fAnimSpeedRange=`floatSliderGrp -q -v $animSpeedRangeGrp`"
		 $animSpeedRangeGrp;
    // Create the float slider for specifying the animation offset variation.
    $animOffsetRangeGrp = `floatSliderGrp -min 0 -max 1
				-fieldMinValue 0
				-fieldMaxValue 1
				-field true
				-value 1
                                -label "Animation Offset Variation"`;
    floatSliderGrp -edit -cc "$fAnimOffsetRange=`floatSliderGrp -q -v $animOffsetRangeGrp`"
		 $animOffsetRangeGrp;
//    separator -height 10;
    // Create the toggle box for colliding with previous agent groups.
//    $collideWithPriorAgentsField = `checkBoxGrp -numberOfCheckBoxes 1
//				-label ""
//				-value1 1
//				-label1 "Collide with Previous Generations of Agents"
//				-columnWidth 2 250
//				-onCommand1 "$collideWithPriorAgents=1"
//				-offCommand1 "$collideWithPriorAgents=0"`;

    setParent $topLayout;


    // Frame for environment variables
    /*
    frameLayout -label "Environment" 
		-borderStyle "etchedIn" 
		-collapsable 1
		-collapse 1;
    columnLayout -adjustableColumn 1 -columnAttach "left" 0;

    // Field for setting the obstacles.
    $collectObstaclesField  = `textFieldButtonGrp -label "Obstacles"
				-buttonLabel "Set Obstacles"
				-editable 0
				-text "(None selected)"
				-columnWidth 2 150
				-buttonCommand collectObstacles`;

    // Create the toggle to connect the current agents with the global forces.
    $globalForcesField = `checkBoxGrp -numberOfCheckBoxes 1
				-label ""
				-value1 0
				-label1 "Connect to Global Forces"
				-columnWidth 2 150
				-onCommand1 "$gforces=1"
				-offCommand1 "$gforces=0"`;

    setParent $topLayout;
    // */

//    // Create buttons
//    rowLayout -numberOfColumns 2 
//		-columnWidth2 200 200
//		-columnAttach 1 "both" 0 
//		-columnAttach 2 "both" 0;
//    string $b1 = `button -label "Create" -height 26 -width 200`;
//    string $b2 = `button -label "Cancel" -height 26 -width 200`;

    // Add command to button to call createCrowd function
    // and then kill the window after script has been executed.
    string $createCmd = "createCrowd $iNumAgents $fCrowdRad $fImpulseRange \
           		 $agentHasAnim $agentHasGoal; ";
    string $cancelCmd = "deleteUI crowdWin; ";

    string $applyButton = getOptionBoxApplyBtn();
    button -edit -label "Create"
		-command $createCmd
		$applyButton;

    string $saveButton = getOptionBoxSaveBtn();
    button -edit //-label "Create"
		-command ($createCmd + $cancelCmd)
		$saveButton;

    string $resetButton = getOptionBoxResetBtn();
    button -edit //-label "Create"
		-command $cancelCmd
		$resetButton;

    //showWindow crowdWin;
    showOptionBox;

} // End crowdSystem

global proc crowdMain()
{
    if (`window -exists crowdWin`)
	deleteUI crowdWin;
    crowdUISetup();
}